{$CLEO}

thread "safk"
0662: "CLEO ON-FOOT ANTI-AFK"
0662: "MADE BY #SAN0"

repeat
    wait 40
until Samp.Available()

0af8: samp_add_message_to_chat "[SAfk]{EAEAEA}: <{007777}OnFoot Anti-Afk{EAEAEA}> sucessfully loaded! Author: {007777}#San0" color 0x007777

0B34: samp register_client_command "safk" to_label @cmd

0AB1: call_scm_func @RUN_CLEO 1 AT LINE @CLEO

const
     // === MAX VALUES === //
    MAX_DELAY = 3600000
    ERR_DELAY = 10000
    // === CHEAT STATE === //
    NULL = 0x0
    ON = 1
    OFF = 0
    // === VARS === //
    _CSTATE = 5@
    P_X = 6@
    P_Y = 7@
    P_Z = 8@  
    R_X = 9@
    R_Y = 10@
    R_Z = 11@
    rnd = 12@
    count = 13@
    params = 14@
    _CDELAY = 15@
    GV = 16@
    struct = 17@
    tmp = 18@
    evar = 19@
    // === CHEAT ACTION === //
    SERR = 0
    SGOTO = 1
    SWAIT = 2
    SCALCULATING = 3
end

while true
    wait 0
    if _CSTATE == ON
    then
        0BFC: set_global_var "SACTION" = SCALCULATING
        00A0: store_actor $PLAYER_ACTOR position_to P_X P_Y P_Z  
        00A0: store_actor $PLAYER_ACTOR position_to R_X R_Y R_Z
        // random pos
        0208: rnd = random_float_in_ranges -10.0 10.0
        005B: R_X += rnd // (float)
        0208: rnd = random_float_in_ranges -10.0 10.0
        005B: R_Y += rnd // (float)
        0085: P_Z = R_Z // (int)
        // free light of road
        if 06BD: no_obstacles_between P_X P_Y P_Z and R_X R_Y R_Z solid 1 car 1 actor 1 object 1 particle 1
        then        
            if and
            gosub @goto_point
            gosub @wait  
            then
                count ++
                0BFC: set_global_var "SCOUNT" = count
            else
                0af8: samp_add_message_to_chat "[SAfk]{EAEAEA}: {ff0000} Fully deactivated, total count %d" color 0x007777 count  
                count = NULL  
                0BFC: set_global_var "SACTION" = NULL
                0BFC: set_global_var "SCOUNT" = NULL
            end                 
        end
    end   
end

:cmd
if _CSTATE == ON
then
    jump @else
end
0B35: samp params = get_last_command_params
if 0AD4: params = scan_string params format "%d" _CDELAY
then
    0af8: samp_add_message_to_chat "[SAfk]{EAEAEA}: {00ff00} Activated {EAEAEA} | Params: %d ms" color 0x007777 _CDELAY  
    0BFC: set_global_var "SAFK" = ON  
    _CSTATE = ON
else   
    0af8: samp_add_message_to_chat "[SAfk]{EAEAEA}: Use {007777}/safk <delay in ms>" color 0x007777   
end    
Samp.CmdRet

:else
0af8: samp_add_message_to_chat "[SAfk]{EAEAEA}: {ff0000} Deactivated" color 0x007777
0af8: samp_add_message_to_chat "[SAfk]{EAEAEA}: {ff0000} NOTE: {EAEAEA} Wait until script calculate count" color 0x007777
0BFC: set_global_var "SAFK" = OFF
_CDELAY = NULL
_CSTATE = OFF
0B43: samp cmd_ret

:wait
const
    timer = 32@
end
0BFC: set_global_var "SACTION" = SWAIT
timer = NULL
while true
    wait 0
    0BFD: GV = get_global_var "SAFK"
    if GV == OFF
    then
        059A:  return_false     
        break
    end
    if timer >= MAX_DELAY
    then
        0af8: samp_add_message_to_chat "[SAfk]{EAEAEA}: Somethink trouble with delay, script {ff0000}unloaded from memory" color 0x007777  
        0ABA: end_custom_thread_named 'safk'    
        wait 50    
        0A92: create_custom_thread "safk.cs"     
        059A:  return_false     
        break
    end
    if 002D: timer >= _CDELAY
    then
        0485:  return_true
        break
    end   
end
return


:goto_point   // by gc0de
const
    timer = 32@
end
timer = NULL
evar = ERR_DELAY
0BFC: set_global_var "SACTION" = SGOTO
repeat
    wait 0       
    0BFD: GV = get_global_var "SAFK"
    if GV == OFF
    then
        059A:  return_false
        break
    end
    if 002D: timer >= evar
    then
        0af8: samp_add_message_to_chat "[SAfk]{EAEAEA}: Somethink trouble with road, actor putted in random point" color 0x007777
        00A1: put_actor $PLAYER_ACTOR at R_X R_Y R_Z
    end
    00A0: store_actor $PLAYER_ACTOR position_to P_X P_Y P_Z
    0063: R_X -= P_X
    0063: R_Y -= P_Y
    0604: get_Z_angle_for_point R_X R_Y store_to P_Z
    005B: R_X += P_X
    005B: R_Y += P_Y
    P_Z *= 0.01745
    0A96: struct = actor $PLAYER_ACTOR struct
    struct += 0x558
    0A8C: write_memory struct size 4 value P_Z virtual_protect 0
    0373: set_camera_directly_behind_player
    tmp = 0xB73458
    tmp += 0x20
    0A8C: write_memory tmp size 1 value 0 virtual_protect 0
    tmp = 0xB73458
    tmp += 0x3
    0A8C: write_memory tmp size 1 value 255 virtual_protect 0  
until 00ED: actor $PLAYER_ACTOR 0 near_point R_X R_Y radius 0.4 0.4 on_foot
return
  
:CLEO
/*
     // === REGISTED GLOBAL VARS === // :
    SAFK, SACTION, SCOUNT
*/
0000:
0AC8: 5@ = allocate_memory_size 128
0B6D: render 4@ = create_font "Comis Sans MS" height 10 flags 14
WHILE TRUE
    wait 0
    0BFD: 0@ = get_global_var "SAFK"
    if 0@ == 0x1
    then
        0B5A: get_screen_resolution 1@ 2@
        2@ /= 2
        0B6A: render draw_box_with_border_pos 0 2@ size 200 100 color 0xAF000000 border_size 5 border_color 0xFF0A217D
        2@ += 15
        0B6F: render font 4@ draw_text "Current action:" pos 10 2@ color 0xFFDEDE28  
        0BFD: 6@ = get_global_var "SACTION"
        if 6@ == 0
        then
            format 5@ "SAFK_EROR"
        end
        if 6@ == 1
        then
            format 5@ "SAFK_GOTO_POINT"
        end
        if 6@ == 2
        then
            format 5@ "SAFK_WAIT_DELAY"
        end
        if 6@ == 3
        then
            format 5@ "SAFK_CALCULATING_COORD"
        end
        2@ += 20
        0B6F: render font 4@ draw_text 5@ pos 10 2@ color 0xFFFF0A3B
        0BFD: 6@ = get_global_var "SCOUNT"
        format 5@ "Current count -> %d" 6@
        2@ += 20
        0B6F: render font 4@ draw_text 5@ pos 10 2@ color 0xFF08EFFF
        0C11: memset destination 5@ value 0x0 size 128
    end
END


:RUN_CLEO
0A9F: 32@ = current_thread_pointer
000A: 32@ += 0x10
0A8D: 32@ = read_memory 32@ size 4 virtual_protect 0
0062: 32@ -= 0@
0AA7: call_function 0x464C20 num_params 1 pop 1 32@ 33@
005A: 32@ += 0@
000A: 33@ += 0x10
0A8C: write_memory 33@ size 4 value 32@ virtual_protect 0
000A: 33@ += 0x2C
for 32@ = 0 to 30
    0A8C: write_memory 33@ size 4 value 1@(32@,30i) virtual_protect 0
    000A: 33@ += 4
end
0AB2: ret 0